6 files changed, 225 insertions, 0 deletions
diff --git a/pkgs/crazydiskinfo/default.nix b/pkgs/crazydiskinfo/default.nix
new file mode 100644
index 0000000..61de338
--- /dev/null
+++ b/pkgs/crazydiskinfo/default.nix
@@ -0,0 +1,41 @@
+{ lib
+, cmake
+, fetchFromGitHub
+, fetchpatch
+, libatasmart
+, ncurses5
+, stdenv
+}:
+
+stdenv.mkDerivation rec {
+  pname = "crazydiskinfo";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "otakuto";
+    repo = pname;
+    rev = "refs/tags/${version}";
+    sha256 = "sha256-+6ShoaggQ256sLSJDj4d16OipUYX/4JjEwLL5hswjiQ=";
+  };
+
+  patches = [
+    # Patch to fix build warnings
+    (fetchpatch {
+      url = "https://github.com/otakuto/crazydiskinfo/compare/1.1.0...8563aa8.diff";
+      sha256 = "sha256-z9aOQFsivu6sYgsZBOlnTvqnoR2ro/jyuO/WOimLSXk=";
+    })
+  ];
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [ libatasmart ncurses5 ];
+
+  cmakeFlags = [ "-DCMAKE_INSTALL_PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "CrazyDiskInfo is an interactive TUI S.M.A.R.T viewer for Unix systems";
+    homepage = "https://github.com/otakuto/crazydiskinfo";
+    mainProgram = "crazy";
+    license = licenses.mit;
+    maintainers = [ maintainers.tjkeller ];
+  };
+}
diff --git a/pkgs/default.nix b/pkgs/default.nix
new file mode 100644
index 0000000..1c0ed23
--- /dev/null
+++ b/pkgs/default.nix
@@ -0,0 +1,31 @@
+{ pkgs, ... }: {
+	nixpkgs.overlays = with pkgs; [
+		(final: prev: {
+			crazydiskinfo = (callPackage ./crazydiskinfo {});
+			lowbat        = (callPackage ./lowbat {});
+			workcentre-7800-series = (callPackage ./xerox-workcentre-7800-series-driver {});
+
+			# Use my vimv-rs until pr gets merged
+			vimv-rs = prev.vimv-rs.overrideAttrs (oldAttrs: {
+				src = fetchFromGitHub {
+					owner = "tjkeller-xyz";
+					repo = "vimv-rs";
+					rev = "5deb76fb81dd4acf3c4809087ff3a1d846ab4769";
+					sha256 = "sha256-XMn+5mIxSEHaR31ixMi6o7PSkN1iYjDT4aOiQkfEwpA=";
+				};
+			});
+
+			# Use my tamzen until pr gets merged
+			tamzen = prev.tamzen.overrideAttrs (oldAttrs: {
+				src = fetchFromGitHub {
+					owner = "tjkeller-xyz";
+					repo = "tamzen-font";
+					rev = "middledot";
+					sha256 = "sha256-mVZ8SdYKTdMG1qBKKYdNjuoYvWkEq2ph2O1ztsNJEhs=";
+				};
+			});
+		})
+		(import ./st/overrides.nix)
+		(import ./xorg/overrides.nix)
+	];
+}
diff --git a/pkgs/lowbat/default.nix b/pkgs/lowbat/default.nix
new file mode 100644
index 0000000..64ec205
--- /dev/null
+++ b/pkgs/lowbat/default.nix
@@ -0,0 +1,28 @@
+{ lib
+, fetchzip
+, glib
+, libnotify
+, pkg-config
+, stdenv
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lowbat";
+  version = "1.2.2";
+
+  src = fetchzip {
+    url = "https://git.tjkeller.xyz/${pname}/snapshot/${pname}-${version}.tar.xz";
+    sha256 = "sha256-utdcY9qoDcrBWnGC8m/LUsnoxQ0ilssPDF44A6D/C+8=";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ libnotify glib ];
+
+  installFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "A minimal battery level monitor daemon, written in C";
+    license = licenses.mit;
+    maintainers = [ maintainers.tjkeller ];
+  };
+}
diff --git a/pkgs/st/overrides.nix b/pkgs/st/overrides.nix
new file mode 100644
index 0000000..2d0a37e
--- /dev/null
+++ b/pkgs/st/overrides.nix
@@ -0,0 +1,19 @@
+final: prev: {
+  st = prev.st.overrideAttrs (finalAttrs: previousAttrs: {
+    version = "tj-0.9.2.3";
+
+    src = prev.fetchgit {
+      url = "https://git.tjkeller.xyz/${previousAttrs.pname}";
+      tag = finalAttrs.version;
+      sha256 = "sha256-SQ62io4LWsPBvX8e9vUwVVXs/2+THoR6ZZoldQ6IUJk=";
+    };
+
+    makeFlags = previousAttrs.makeFlags ++ [ "CFLAGS=-Ofast" ];
+    buildInputs = with prev.pkgs.xorg; previousAttrs.buildInputs ++ [ libXcursor libXext ];
+
+    meta = with prev.lib; previousAttrs.meta // {
+      homepage = "https://git.tjkeller.xyz/st";
+      maintainers = previousAttrs.meta.maintainers ++ [ maintainers.tjkeller ];
+    };
+  });
+}
diff --git a/pkgs/xerox-workcentre-7800-series-driver/default.nix b/pkgs/xerox-workcentre-7800-series-driver/default.nix
new file mode 100644
index 0000000..cfdaaae
--- /dev/null
+++ b/pkgs/xerox-workcentre-7800-series-driver/default.nix
@@ -0,0 +1,86 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+  dpkg,
+  autoPatchelfHook,
+  cups,
+  xorg,
+}:
+let
+  debPlatform =
+    if stdenv.hostPlatform.system == "x86_64-linux" then
+      "x86_64"
+    else if stdenv.hostPlatform.system == "i686-linux" then
+      "i686"
+    else
+      throw "Unsupported system: ${stdenv.hostPlatform.system}";
+in
+stdenv.mkDerivation rec {
+  pname = "xerox-workcentre-7800-series-driver";
+  version = "5.20.661.4684";
+  debpkg = "XeroxOfficev5Pkg-Linux${debPlatform}-${version}.deb";
+
+  src = fetchurl {
+    url = "https://download.support.xerox.com/pub/drivers/CQ8580/drivers/linux/pt_BR/${debpkg}";
+    sha256 = "014k0r9ij3401mnab1qzv96bjl9x7rf11aw1ibf0q370pk9jqqjb";  # TODO correct hash for i686
+  };
+
+  nativeBuildInputs = [ dpkg autoPatchelfHook ];
+  # TODO add support for disable xorg
+  buildInputs = [
+    cups
+    stdenv.cc.cc.lib
+    xorg.libX11
+    xorg.libXrender
+    xorg.libXfixes
+    xorg.libXdamage
+    xorg.libXcomposite
+    xorg.libXcursor
+    xorg.libXrandr
+    xorg.libXext
+    xorg.libXinerama
+  ];
+
+  sourceRoot = ".";
+  unpackCmd = "dpkg-deb -x $curSrc .";
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+
+    # Copy and patch the binaries and libraries
+    cp -r opt $out/
+    cp -r usr $out/
+
+    # Move the PPD to CUPS model dir
+    mkdir -p $out/share/cups/model
+    cp opt/XeroxOffice/prtsys/ppd/*.ppd $out/share/cups/model/
+
+    # Install the CUPS filters
+    mkdir -p $out/lib/cups/filter
+    cp usr/lib/cups/filter/* $out/lib/cups/filter/
+
+    # Install man pages
+    mkdir -p $out/share/man
+    cp -r usr/share/man/* $out/share/man/
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Xerox WorkCentre 7800 Series Linux Printer Driver";
+    longDescription = ''
+      WorkCentre 7830/7835/7845/7855
+    '';
+    homepage = "https://www.support.xerox.com/en-us/product/workcentre-7800-series/downloads?platform=linux";
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+			#license = licenses.unfree;
+    maintainers = [];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/xorg/overrides.nix b/pkgs/xorg/overrides.nix
new file mode 100644
index 0000000..7225431
--- /dev/null
+++ b/pkgs/xorg/overrides.nix
@@ -0,0 +1,20 @@
+final: prev: {
+	xorg = prev.xorg // {
+		# Apply startx patch to create serverauth file in /tmp instead of home directory
+		xinit = (prev.xorg.xinit.overrideAttrs (finalAttrs: previousAttrs: {
+			version = "1.4.4";
+			patchtag = "${finalAttrs.version}-1";  # Archlinux xinit package tagged release to fetch patch from
+			# Override src since is hardcoded to 1.4.2
+			src = prev.fetchurl {
+				url = "mirror://xorg/individual/app/xinit-${finalAttrs.version}.tar.xz";
+				sha256 = "sha256-QKR8ehZMf5gc43h7Szf35BH7QyMdzeVD1wCUB12s/vk=";
+			};
+			patches = [
+				(prev.fetchpatch {
+					url = "https://gitlab.archlinux.org/archlinux/packaging/packages/xorg-xinit/-/raw/${finalAttrs.patchtag}/06_move_serverauthfile_into_tmp.diff";
+					sha256 = "1whzs5bw7ph12r3abs1g9fydibkr291jh56a0zp17d4x070jnkda";
+				})
+			];
+		}));
+	};
+}