blob: 92b76a94c69db8004968ba2cff1ca58e9532b632 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
rec {
description = "TimmyOS System Config";
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";
nixpkgs-unstable.url = "github:nixos/nixpkgs/nixos-unstable";
sops-nix = {
url = "github:Mic92/sops-nix";
inputs.nixpkgs.follows = "nixpkgs";
};
home-manager = {
url = "github:nix-community/home-manager/release-25.11";
inputs.nixpkgs.follows = "nixpkgs";
};
arkenfox = {
url = "github:dwarfmaster/arkenfox-nixos";
inputs.nixpkgs.follows = "nixpkgs";
};
reposync = {
url = "git://git.tjkeller.xyz/hm-reposync";
inputs.nixpkgs.follows = "nixpkgs";
};
};
outputs = { nixpkgs, home-manager, ... }@inputs: let
extLib = nixpkgs.lib.extend (final: prev: import ./lib);
extLibHomeManagerStandalone = nixpkgs.lib.extend (final: prev: import ./lib/home-manager);
homeManagerModules = [
inputs.arkenfox.hmModules.arkenfox
inputs.reposync.hmModules.reposync
./home-manager
];
mkNixosConfiguration = system: hostname: nixpkgs.lib.nixosSystem {
inherit system;
specialArgs = {
inherit inputs;
inherit hostname;
lib = extLib;
};
modules = [
./hosts/${hostname}/configuration.nix
./hosts/${hostname}/hardware-configuration.nix
./archetypes
./nixos
./pkgs
./users
inputs.sops-nix.nixosModules.sops
home-manager.nixosModules.home-manager {
home-manager = {
backupFileExtension = "backup"; # In case file is overwritten
useGlobalPkgs = true;
useUserPackages = true;
sharedModules = homeManagerModules;
};
}
];
};
mkNixosConfigurations = hostsBySystem: builtins.listToAttrs (
builtins.concatMap (system:
map (host: {
name = host;
value = mkNixosConfiguration system host;
}) hostsBySystem.${system}
) (builtins.attrNames hostsBySystem)
);
mkHomeConfiguration = user: system: hostname: home-manager.lib.homeManagerConfiguration {
pkgs = nixpkgs.legacyPackages.${system};
extraSpecialArgs = {
inherit inputs;
inherit hostname;
lib = extLibHomeManagerStandalone;
};
modules = homeManagerModules ++ [
./hosts/${hostname}/home-${user}/configuration.nix
./archetypes/profiles
./pkgs
./users/default-home.nix
];
};
mkHomeConfigurations = hostsBySystem: builtins.listToAttrs (
builtins.concatMap (system:
map (host: {
name = host;
value = mkHomeConfiguration "timmy" system host; # TODO
}) hostsBySystem.${system}
) (builtins.attrNames hostsBySystem)
);
in {
# Configured system hostnames go here under their respective system architecture
nixosConfigurations = mkNixosConfigurations {
x86_64-linux = [
"T495"
"X230"
"flex-wg-router"
"hp-envy-office"
"libreX60"
"optiplex"
"poweredge"
];
aarch64-linux = [
"piframe"
];
};
homeConfigurations = mkHomeConfigurations {
x86_64-linux = [
"libreX60"
];
};
};
}
|
