6 files changed, 161 insertions, 96 deletions
diff --git a/derivations/crazydiskinfo/default.nix b/derivations/crazydiskinfo/default.nix
new file mode 100644
index 0000000..61de338
--- /dev/null
+++ b/derivations/crazydiskinfo/default.nix
@@ -0,0 +1,41 @@
+{ lib
+, cmake
+, fetchFromGitHub
+, fetchpatch
+, libatasmart
+, ncurses5
+, stdenv
+}:
+
+stdenv.mkDerivation rec {
+  pname = "crazydiskinfo";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "otakuto";
+    repo = pname;
+    rev = "refs/tags/${version}";
+    sha256 = "sha256-+6ShoaggQ256sLSJDj4d16OipUYX/4JjEwLL5hswjiQ=";
+  };
+
+  patches = [
+    # Patch to fix build warnings
+    (fetchpatch {
+      url = "https://github.com/otakuto/crazydiskinfo/compare/1.1.0...8563aa8.diff";
+      sha256 = "sha256-z9aOQFsivu6sYgsZBOlnTvqnoR2ro/jyuO/WOimLSXk=";
+    })
+  ];
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [ libatasmart ncurses5 ];
+
+  cmakeFlags = [ "-DCMAKE_INSTALL_PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "CrazyDiskInfo is an interactive TUI S.M.A.R.T viewer for Unix systems";
+    homepage = "https://github.com/otakuto/crazydiskinfo";
+    mainProgram = "crazy";
+    license = licenses.mit;
+    maintainers = [ maintainers.tjkeller ];
+  };
+}
diff --git a/derivations/lowbat/default.nix b/derivations/lowbat/default.nix
index 02ff111..64ec205 100644
--- a/derivations/lowbat/default.nix
+++ b/derivations/lowbat/default.nix
@@ -1,28 +1,26 @@
-{ pkgs ? import <nixpkgs> {} }:
+{ lib
+, fetchzip
+, glib
+, libnotify
+, pkg-config
+, stdenv
+}:
 
-pkgs.stdenv.mkDerivation rec {
+stdenv.mkDerivation rec {
   pname = "lowbat";
-  version = "1.2.1";
+  version = "1.2.2";
 
-  src = pkgs.fetchzip {
+  src = fetchzip {
     url = "https://git.tjkeller.xyz/${pname}/snapshot/${pname}-${version}.tar.xz";
-    sha256 = "sha256-xsUHdmicHX/fQQgojVjWfzI82e4NezkmlACOpdPxLE0=";
+    sha256 = "sha256-utdcY9qoDcrBWnGC8m/LUsnoxQ0ilssPDF44A6D/C+8=";
   };
 
-  nativeBuildInputs = [ pkgs.pkg-config ];
-  buildInputs = [ pkgs.libnotify pkgs.glib ];
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ libnotify glib ];
 
-  buildPhase = ''
-    make
-  '';
+  installFlags = [ "PREFIX=$(out)" ];
 
-  installPhase = ''
-    mkdir -p $out/bin $out/share/man/man1
-    cp lowbat $out/bin/
-    cp lowbat.1 $out/share/man/man1/
-  '';
-
-  meta = with pkgs.lib; {
+  meta = with lib; {
     description = "A minimal battery level monitor daemon, written in C";
     license = licenses.mit;
     maintainers = [ maintainers.tjkeller ];
diff --git a/derivations/pavolctld/default.nix b/derivations/pavolctld/default.nix
deleted file mode 100644
index c78e3fe..0000000
--- a/derivations/pavolctld/default.nix
+++ /dev/null
@@ -1,29 +0,0 @@
-{ pkgs ? import <nixpkgs> {} }:
-
-pkgs.stdenv.mkDerivation rec {
-  pname = "pavolctld";
-  version = "1.0.0";
-
-  src = pkgs.fetchzip {
-    url = "https://git.tjkeller.xyz/${pname}/snapshot/${pname}-${version}.tar.xz";
-    sha256 = "sha256-eJ5njP2wu2kxsNgDdULOaATJJarLh+LkM5M9+kujRt4=";
-  };
-
-  buildInputs = [ pkgs.libpulseaudio ];
-
-  buildPhase = ''
-    make
-  '';
-
-  installPhase = ''
-    mkdir -p $out/bin $out/share/man/man1
-    cp pavolctld $out/bin/
-    cp pavolctld.1 $out/share/man/man1/
-  '';
-
-  meta = with pkgs.lib; {
-    description = "A minimal PulseAudio volume control/monitoring daemon";
-    license = licenses.mit;
-    maintainers = [ maintainers.tjkeller ];
-  };
-}
diff --git a/derivations/st/default.nix b/derivations/st/default.nix
deleted file mode 100644
index eb7c6bc..0000000
--- a/derivations/st/default.nix
+++ /dev/null
@@ -1,50 +0,0 @@
-{
-  lib,
-  stdenv,
-  fetchzip,
-  fontconfig,
-  libX11,
-  libXcursor,
-  libXext,
-  libXft,
-  ncurses,
-  pkg-config,
-}:
-
-stdenv.mkDerivation rec {
-  pname = "st";
-  version = "tj-0.9.2.2";
-
-  src = fetchzip {
-    url = "https://git.tjkeller.xyz/${pname}/snapshot/${pname}-${version}.tar.xz";
-    sha256 = "sha256-p1u7TEeLeC5Kjvi8na4YhyQQ0qdPaUWZL6hq9O4HaKA=";
-  };
-
-  nativeBuildInputs = [
-    pkg-config
-  ];
-  buildInputs = [
-    fontconfig
-    libX11
-    libXcursor
-    libXext
-    libXft
-    ncurses
-  ];
-
-  installPhase = ''
-    runHook preInstall
-
-    TERMINFO=$out/share/terminfo make install PREFIX=$out
-
-    runHook postInstall
-  '';
-
-  meta = with lib; {
-    homepage = "https://git.tjkeller.xyz/st";
-    description = "My st with various patches";
-    mainProgram = "st";
-    license = licenses.mit;
-    maintainers = [ maintainers.tjkeller ];
-  };
-}
diff --git a/derivations/st/overrides.nix b/derivations/st/overrides.nix
new file mode 100644
index 0000000..2d0a37e
--- /dev/null
+++ b/derivations/st/overrides.nix
@@ -0,0 +1,19 @@
+final: prev: {
+  st = prev.st.overrideAttrs (finalAttrs: previousAttrs: {
+    version = "tj-0.9.2.3";
+
+    src = prev.fetchgit {
+      url = "https://git.tjkeller.xyz/${previousAttrs.pname}";
+      tag = finalAttrs.version;
+      sha256 = "sha256-SQ62io4LWsPBvX8e9vUwVVXs/2+THoR6ZZoldQ6IUJk=";
+    };
+
+    makeFlags = previousAttrs.makeFlags ++ [ "CFLAGS=-Ofast" ];
+    buildInputs = with prev.pkgs.xorg; previousAttrs.buildInputs ++ [ libXcursor libXext ];
+
+    meta = with prev.lib; previousAttrs.meta // {
+      homepage = "https://git.tjkeller.xyz/st";
+      maintainers = previousAttrs.meta.maintainers ++ [ maintainers.tjkeller ];
+    };
+  });
+}
diff --git a/derivations/xerox-workcentre-7800-series-driver/default.nix b/derivations/xerox-workcentre-7800-series-driver/default.nix
new file mode 100644
index 0000000..cfdaaae
--- /dev/null
+++ b/derivations/xerox-workcentre-7800-series-driver/default.nix
@@ -0,0 +1,86 @@
+{
+  stdenv,
+  lib,
+  fetchurl,
+  dpkg,
+  autoPatchelfHook,
+  cups,
+  xorg,
+}:
+let
+  debPlatform =
+    if stdenv.hostPlatform.system == "x86_64-linux" then
+      "x86_64"
+    else if stdenv.hostPlatform.system == "i686-linux" then
+      "i686"
+    else
+      throw "Unsupported system: ${stdenv.hostPlatform.system}";
+in
+stdenv.mkDerivation rec {
+  pname = "xerox-workcentre-7800-series-driver";
+  version = "5.20.661.4684";
+  debpkg = "XeroxOfficev5Pkg-Linux${debPlatform}-${version}.deb";
+
+  src = fetchurl {
+    url = "https://download.support.xerox.com/pub/drivers/CQ8580/drivers/linux/pt_BR/${debpkg}";
+    sha256 = "014k0r9ij3401mnab1qzv96bjl9x7rf11aw1ibf0q370pk9jqqjb";  # TODO correct hash for i686
+  };
+
+  nativeBuildInputs = [ dpkg autoPatchelfHook ];
+  # TODO add support for disable xorg
+  buildInputs = [
+    cups
+    stdenv.cc.cc.lib
+    xorg.libX11
+    xorg.libXrender
+    xorg.libXfixes
+    xorg.libXdamage
+    xorg.libXcomposite
+    xorg.libXcursor
+    xorg.libXrandr
+    xorg.libXext
+    xorg.libXinerama
+  ];
+
+  sourceRoot = ".";
+  unpackCmd = "dpkg-deb -x $curSrc .";
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+
+    # Copy and patch the binaries and libraries
+    cp -r opt $out/
+    cp -r usr $out/
+
+    # Move the PPD to CUPS model dir
+    mkdir -p $out/share/cups/model
+    cp opt/XeroxOffice/prtsys/ppd/*.ppd $out/share/cups/model/
+
+    # Install the CUPS filters
+    mkdir -p $out/lib/cups/filter
+    cp usr/lib/cups/filter/* $out/lib/cups/filter/
+
+    # Install man pages
+    mkdir -p $out/share/man
+    cp -r usr/share/man/* $out/share/man/
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Xerox WorkCentre 7800 Series Linux Printer Driver";
+    longDescription = ''
+      WorkCentre 7830/7835/7845/7855
+    '';
+    homepage = "https://www.support.xerox.com/en-us/product/workcentre-7800-series/downloads?platform=linux";
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+			#license = licenses.unfree;
+    maintainers = [];
+    platforms = platforms.linux;
+  };
+}